Microsoft Office Tutorials and References
In Depth Information
A8:0
A9: =WENN(ZEILEN(A$8:A9)>$B$1;"";A8+1)
B8:
=WENN(A8="";"";TEXT(DATUM(
JAHR($B$2)+WENN($B$3="J";A8*$B$4;0);
MONAT($B$2)+WENN($B$3="M";A8*$B$4;0);
TAG($B$2)+WENN($B$3="T";A8*$B$4;0));$B$5))
A9 und B8 werden so weit nach unten kopiert, wie der Zeitstrahl maximal lang sein
könnte. Wie funktioniert die Formel in B8? Die Formel
=DATUM(JAHR($B$2);MONAT($B$2);TAG($B$2))
würde genau das Datum erzeugen, das in B2 als Startdatum vorgegeben wird. Die
drei WENN-Prüfungen
WENN($B$3="J";A8*$B$4;0)
WENN($B$3="M";A8*$B$4;0)
WENN($B$3="T";A8*$B$4;0)
addieren dann je nach Eingabe in B3 entweder zum Jahr, zum Monat oder zum Tag
A8*$B$4 Einheiten dazu. Die Funktion TEXT wandelt das resultierende Datum schließ-
lich in das gewünschte Format um. Zum Beispiel:
B13:
TEXT(DATUM(2001+0;1+5;1+0);"MMM JJ") = "Jun 01"
Spalte E zeigt einen Sonderfall, der bei Anwendung dieser Berechnung Probleme
macht. Angenommen Sie wollen bei Ihrem Zeitstrahl immer den letzten eines
Monats erhalten. Schwierig wird dies durch die unterschiedliche Länge der Monate.
In Spalte E sieht man, wie die gleiche Formel aus Spalte B zu teilweise falschen
Ergebnissen führt. Abhilfe verschafft in diesem Sonderfall die Lösung in Spalte F:
F9: =DATUM(JAHR(F8);MONAT(F8)+2;0)
Der Trick funktioniert nach dem Prinzip: Der nullte Tag des übernächsten Monats
entspricht dem letzten Tag des folgenden Monats. Dafür stehen die Parameter +2;0 .
Beispiel:
=TEXT(DATUM(2001;1+2;0); "TT.MM.JJ")=28.02.2001
Mit der Formel kann man übrigens grundsätzlich prüfen, ob ein Jahr ein Schaltjahr
ist oder nicht. Angenommen in A1 steht eine einfache Jahreszahl:
A1:2004
Search JabSto ::




Custom Search